mini/utils_asm.S at master · Wiivolution/mini · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
/*
	mini - a Free Software replacement for the Nintendo/BroadOn IOS.
	random utilities

Copyright (C) 2008, 2009	Hector Martin "marcan" <marcan@marcansoft.com>

# This code is licensed to you under the terms of the GNU GPL, version 2;
# see file COPYING or http://www.gnu.org/licenses/old-licenses/gpl-2.0.txt
*/

.arm

.globl memcpy32
.type memcpy32, %function
.globl memcpy16
.type memcpy16, %function
.globl memcpy8
.type memcpy8, %function
.globl memset32
.type memset32, %function
.globl memset16
.type memset16, %function
.globl memset8
.type memset8, %function

.text

memcpy32:
	bics	r2, #3
	bxeq	lr
1:	ldr		r3, [r1],#4
	str		r3, [r0],#4
	subs	r2, #4
	bne		1b
	bx		lr
.size memcpy32, . - memcpy32

memset32:
	bics	r2, #3
	bxeq	lr
1:	str		r1, [r0],#4
	subs	r2, #4
	bne		1b
	bx		lr
.size memset32, . - memset32

memcpy16:
	bics	r2, #1
	bxeq	lr
1:	ldrh	r3, [r1],#2
	strh	r3, [r0],#2
	subs	r2, #2
	bne		1b
	bx		lr
.size memcpy16, . - memcpy16

memset16:
	bics	r2, #1
	bxeq	lr
1:	strh	r1, [r0],#2
	subs	r2, #2
	bne		1b
	bx		lr
.size memset16, . - memset16

memcpy8:
	cmp		r2, #0
	bxeq	lr
1:	ldrb	r3, [r1],#1
	strb	r3, [r0],#1
	subs	r2, #1
	bne		1b
	bx		lr
.size memcpy8, . - memcpy8

memset8:
	cmp		r2, #0
	bxeq	lr
1:	strb	r1, [r0],#1
	subs	r2, #1
	bne		1b
	bx		lr
.size memset8, . - memset8